%--------------------------------------------------------------------------
% File     : MGT113+1 : TPTP v9.3.1. Released v9.3.0.
% Domain   : Management
% Problem  : A1-A3+B1: violation triggers norm state change requiring Power
% Version  : Especial.
% English  : proh(f1) + has_rem(f1) + does(marketplace,distrib,concert_ds).
%            B1: violation => NormStateChange.
%            A1: NormStateChange => InstEvent.
%            A2: InstEvent => competent agent.
%            A3: competence => Power+Subjection pair.
%            Conjecture: Power+Subjection in fresh rho_R founded via 
%            founds_rem at e1.

% Refs     : [MC+26] Mustafa et al. (2026), Axis Decomposition for ODRL
% Source   : [MC+26]
% Names    : GRND017-violation-chain-1.p [MC+26]

% Status   : Theorem
% Rating   : 0.00 v9.3.0
% Syntax   : Number of formulae    :   23 (  14 unt;   0 def)
%            Number of atoms       :   86 (   0 equ)
%            Maximal formula atoms :   16 (   3 avg)
%            Number of connectives :   63 (   0   ~;   0   |;  55   &)
%                                         (   0 <=>;   8  =>;   0  <=;   0 <~>)
%            Maximal formula depth :   19 (   5 avg)
%            Maximal term depth    :    2 (   1 avg)
%            Number of predicates  :   28 (  28 usr;   0 prp; 1-5 aty)
%            Number of functors    :    9 (   9 usr;   7 con; 0-1 aty)
%            Number of variables   :   50 (  35   !;  15   ?)
% SPC      : FOF_THM_RFO_NEQ

% Comments : 
%--------------------------------------------------------------------------
%----Layer 1: Problem-specific axioms (subset of Ax5.1-5.11, A1-A3, B1-B3)
fof(ax_proh_relator_conduct,axiom,
    ! [F,X,Y,A,T,E] :
      ( ( proh(F)
        & aee(F,X)
        & aer(F,Y)
        & act(F,A)
        & tgt(F,T)
        & activates(E,F) )
     => ? [Rho,D,C] :
          ( founds(E,Rho,F)
          & duty(D)
          & bearer(D,X)
          & cnt(D,rfr(A),T)
          & part_of(D,Rho)
          & right(C)
          & bearer(C,Y)
          & cnt(C,rfr(A),T)
          & part_of(C,Rho) ) ) ).

fof(ax_proh_relator_remedy,axiom,
    ! [F,X,Y,A,T,E] :
      ( ( proh(F)
        & has_rem(F)
        & aee(F,X)
        & aer(F,Y)
        & act(F,A)
        & tgt(F,T)
        & activates(E,F) )
     => ? [RhoR,Pw,S] :
          ( founds_rem(E,RhoR,F)
          & power(Pw)
          & bearer(Pw,Y)
          & cnt(Pw,decl(A),T)
          & part_of(Pw,RhoR)
          & subjection(S)
          & bearer(S,X)
          & cnt(S,decl(A),T)
          & part_of(S,RhoR) ) ) ).

fof(ax_A1,axiom,
    ! [X,A,T,Q] :
      ( norm_state_change(X,A,T,Q)
     => ? [E] :
          ( inst_event(E)
          & triggers(E,X,A,T,Q) ) ) ).

fof(ax_A2,axiom,
    ! [E] :
      ( inst_event(E)
     => ? [Y] : competent_for(Y,E) ) ).

fof(ax_A3,axiom,
    ! [Y,E] :
      ( competent_for(Y,E)
     => ? [Pw,S,X] :
          ( power(Pw)
          & bearer(Pw,Y)
          & about_event(Pw,E)
          & subjection(S)
          & bearer(S,X)
          & about_event(S,E) ) ) ).

fof(ax_B1,axiom,
    ! [F,X,A,T] :
      ( ( proh(F)
        & has_rem(F)
        & act(F,A)
        & tgt(F,T)
        & aee(F,X)
        & does(X,A,T) )
     => ? [B] :
          ( rem_act(F,B)
          & norm_state_change(X,B,T,duty_rem) ) ) ).

fof(ax_B2,axiom,
    ! [Pw,A,T,Rho,E,R] :
      ( ( power(Pw)
        & cnt(Pw,decl(A),T)
        & part_of(Pw,Rho)
        & founds_rem(E,Rho,R) )
     => about_event(Pw,E) ) ).

fof(ax_B3,axiom,
    ! [S,A,T,Rho,E,R] :
      ( ( subjection(S)
        & cnt(S,decl(A),T)
        & part_of(S,Rho)
        & founds_rem(E,Rho,R) )
     => about_event(S,E) ) ).

%----Ground instance (gamma)
fof(agent_marketplace,axiom,
    agent(marketplace) ).

fof(agent_philharmonie,axiom,
    agent(philharmonie) ).

fof(action_distrib,axiom,
    action(distrib) ).

fof(target_concert,axiom,
    target(concert_ds) ).

fof(rule_f1,axiom,
    rule(f1) ).

fof(event_e1,axiom,
    event(e1) ).

fof(proh_f1,axiom,
    proh(f1) ).

fof(rem_f1,axiom,
    has_rem(f1) ).

fof(aee_f1,axiom,
    aee(f1,marketplace) ).

fof(aer_f1,axiom,
    aer(f1,philharmonie) ).

fof(act_f1,axiom,
    act(f1,distrib) ).

fof(tgt_f1,axiom,
    tgt(f1,concert_ds) ).

fof(act_e1_f1,axiom,
    activates(e1,f1) ).

fof(marketplace_does,axiom,
    does(marketplace,distrib,concert_ds) ).

fof(conjecture,conjecture,
    ? [RhoR,Pw,S] :
      ( founds_rem(e1,RhoR,f1)
      & power(Pw)
      & bearer(Pw,philharmonie)
      & cnt(Pw,decl(distrib),concert_ds)
      & part_of(Pw,RhoR)
      & about_event(Pw,e1)
      & subjection(S)
      & bearer(S,marketplace)
      & cnt(S,decl(distrib),concert_ds)
      & part_of(S,RhoR)
      & about_event(S,e1) ) ).

%--------------------------------------------------------------------------