TPTP Problem File: MGT109+1.p
View Solutions
- Solve Problem
%--------------------------------------------------------------------------
% File : MGT109+1 : TPTP v9.3.1. Released v9.3.0.
% Domain : Management
% Problem : Full axiom set consistency
% Version : Especial.
% English : The full axiom set (Ax5.1-5.11, A1-A3, B1-B3) is satisfiable.
% Minimal model: one perm rule, one agent pair, one action, one
% target.
% Refs : [MC+26] Mustafa et al. (2026), Axis Decomposition for ODRL
% Source : [MC+26]
% Names : GRND001-1.p [MC+26]
% Status : Satisfiable
% Rating : 0.33 v9.3.0
% Syntax : Number of formulae : 40 ( 12 unt; 0 def)
% Number of atoms : 234 ( 14 equ)
% Maximal formula atoms : 16 ( 5 avg)
% Number of connectives : 195 ( 1 ~; 2 |; 152 &)
% ( 4 <=>; 36 =>; 0 <=; 0 <~>)
% Maximal formula depth : 19 ( 8 avg)
% Maximal term depth : 2 ( 1 avg)
% Number of predicates : 40 ( 38 usr; 1 prp; 0-5 aty)
% Number of functors : 9 ( 9 usr; 7 con; 0-1 aty)
% Number of variables : 153 ( 123 !; 30 ?)
% SPC : FOF_SAT_RFO_SEQ
% Comments : Foundational ontology tier. FOIS 2026 benchmark.
% : inline Layer 1 axiom subset (fof_axioms key).
%--------------------------------------------------------------------------
%----Layer 1: Problem-specific axioms (subset of Ax5.1-5.11, A1-A3, B1-B3)
fof(ax_perm_relator_weak,axiom,
! [P,X,Y,A,T,E] :
( ( perm(P)
& aee(P,X)
& aer(P,Y)
& act(P,A)
& tgt(P,T)
& activates(E,P) )
=> ? [Rho,L,N] :
( founds(E,Rho,P)
& permission(L)
& bearer(L,X)
& cnt(L,A,T)
& part_of(L,Rho)
& no_right(N)
& bearer(N,Y)
& cnt(N,A,T)
& part_of(N,Rho) ) ) ).
fof(ax_perm_relator_strong,axiom,
! [P,X,Y,A,T,E] :
( ( perm(P)
& strong(P)
& aee(P,X)
& aer(P,Y)
& act(P,A)
& tgt(P,T)
& activates(E,P) )
=> ? [RhoI,Im,Db] :
( founds_imm(E,RhoI,P)
& immunity(Im)
& bearer(Im,X)
& cnt(Im,A,T)
& part_of(Im,RhoI)
& disability(Db)
& bearer(Db,Y)
& cnt(Db,A,T)
& part_of(Db,RhoI) ) ) ).
fof(ax_proh_relator_conduct,axiom,
! [F,X,Y,A,T,E] :
( ( proh(F)
& aee(F,X)
& aer(F,Y)
& act(F,A)
& tgt(F,T)
& activates(E,F) )
=> ? [Rho,D,C] :
( founds(E,Rho,F)
& duty(D)
& bearer(D,X)
& cnt(D,rfr(A),T)
& part_of(D,Rho)
& right(C)
& bearer(C,Y)
& cnt(C,rfr(A),T)
& part_of(C,Rho) ) ) ).
fof(ax_proh_relator_remedy,axiom,
! [F,X,Y,A,T,E] :
( ( proh(F)
& has_rem(F)
& aee(F,X)
& aer(F,Y)
& act(F,A)
& tgt(F,T)
& activates(E,F) )
=> ? [RhoR,Pw,S] :
( founds_rem(E,RhoR,F)
& power(Pw)
& bearer(Pw,Y)
& cnt(Pw,decl(A),T)
& part_of(Pw,RhoR)
& subjection(S)
& bearer(S,X)
& cnt(S,decl(A),T)
& part_of(S,RhoR) ) ) ).
fof(ax_obl_relator,axiom,
! [D,X,Y,A,T,E] :
( ( obl(D)
& aee(D,X)
& aer(D,Y)
& act(D,A)
& tgt(D,T)
& activates(E,D) )
=> ? [Rho,Du,C] :
( founds(E,Rho,D)
& duty(Du)
& bearer(Du,X)
& cnt(Du,A,T)
& part_of(Du,Rho)
& right(C)
& bearer(C,Y)
& cnt(C,A,T)
& part_of(C,Rho) ) ) ).
fof(ax_unique_founding,axiom,
! [R,E,Rho1,Rho2] :
( ( founds(E,Rho1,R)
& founds(E,Rho2,R) )
=> Rho1 = Rho2 ) ).
fof(ax_unique_event,axiom,
! [R,E1,E2,Rho] :
( ( founds(E1,Rho,R)
& founds(E2,Rho,R) )
=> E1 = E2 ) ).
fof(ax_unique_founding_rem,axiom,
! [R,E,Rho1,Rho2] :
( ( founds_rem(E,Rho1,R)
& founds_rem(E,Rho2,R) )
=> Rho1 = Rho2 ) ).
fof(ax_unique_event_rem,axiom,
! [R,E1,E2,Rho] :
( ( founds_rem(E1,Rho,R)
& founds_rem(E2,Rho,R) )
=> E1 = E2 ) ).
fof(ax_unique_founding_imm,axiom,
! [R,E,Rho1,Rho2] :
( ( founds_imm(E,Rho1,R)
& founds_imm(E,Rho2,R) )
=> Rho1 = Rho2 ) ).
fof(ax_unique_event_imm,axiom,
! [R,E1,E2,Rho] :
( ( founds_imm(E1,Rho,R)
& founds_imm(E2,Rho,R) )
=> E1 = E2 ) ).
fof(ax_odrl_rel_typing,axiom,
! [E,Rho,R] :
( ( founds(E,Rho,R)
& ( perm(R)
| proh(R)
| obl(R) ) )
=> odrl_rel(Rho) ) ).
fof(ax_odrl_rel_typing_rem,axiom,
! [E,Rho,R] :
( ( founds_rem(E,Rho,R)
& proh(R) )
=> odrl_rel(Rho) ) ).
fof(ax_odrl_rel_typing_imm,axiom,
! [E,Rho,R] :
( ( founds_imm(E,Rho,R)
& perm(R) )
=> odrl_rel(Rho) ) ).
fof(ax_correlativity_permission,axiom,
! [Rho,A,T] :
( odrl_rel(Rho)
=> ( ? [L] :
( permission(L)
& part_of(L,Rho)
& cnt(L,A,T)
& ! [L2] :
( ( permission(L2)
& part_of(L2,Rho)
& cnt(L2,A,T) )
=> L2 = L ) )
<=> ? [N] :
( no_right(N)
& part_of(N,Rho)
& cnt(N,A,T)
& ! [M] :
( ( no_right(M)
& part_of(M,Rho)
& cnt(M,A,T) )
=> M = N ) ) ) ) ).
fof(ax_correlativity_duty,axiom,
! [Rho,A,T] :
( odrl_rel(Rho)
=> ( ? [D] :
( duty(D)
& part_of(D,Rho)
& cnt(D,A,T)
& ! [D2] :
( ( duty(D2)
& part_of(D2,Rho)
& cnt(D2,A,T) )
=> D2 = D ) )
<=> ? [C] :
( right(C)
& part_of(C,Rho)
& cnt(C,A,T)
& ! [K] :
( ( right(K)
& part_of(K,Rho)
& cnt(K,A,T) )
=> K = C ) ) ) ) ).
fof(ax_correlativity_power,axiom,
! [Rho,A,T] :
( odrl_rel(Rho)
=> ( ? [Pw] :
( power(Pw)
& part_of(Pw,Rho)
& cnt(Pw,A,T)
& ! [Pw2] :
( ( power(Pw2)
& part_of(Pw2,Rho)
& cnt(Pw2,A,T) )
=> Pw2 = Pw ) )
<=> ? [S] :
( subjection(S)
& part_of(S,Rho)
& cnt(S,A,T)
& ! [S2] :
( ( subjection(S2)
& part_of(S2,Rho)
& cnt(S2,A,T) )
=> S2 = S ) ) ) ) ).
fof(ax_correlativity_immunity,axiom,
! [Rho,A,T] :
( odrl_rel(Rho)
=> ( ? [Im] :
( immunity(Im)
& part_of(Im,Rho)
& cnt(Im,A,T)
& ! [Im2] :
( ( immunity(Im2)
& part_of(Im2,Rho)
& cnt(Im2,A,T) )
=> Im2 = Im ) )
<=> ? [Db] :
( disability(Db)
& part_of(Db,Rho)
& cnt(Db,A,T)
& ! [Db2] :
( ( disability(Db2)
& part_of(Db2,Rho)
& cnt(Db2,A,T) )
=> Db2 = Db ) ) ) ) ).
fof(ax_cross_relator,axiom,
! [L,D,X,A,T] :
( ( permission(L)
& bearer(L,X)
& cnt(L,A,T)
& duty(D)
& bearer(D,X)
& cnt(D,rfr(A),T) )
=> $false ) ).
fof(ax_conflict,lemma,
! [Rho,L,D,X,A,T] :
( ( part_of(L,Rho)
& part_of(D,Rho)
& permission(L)
& duty(D)
& bearer(L,X)
& bearer(D,X)
& cnt(L,A,T)
& cnt(D,rfr(A),T) )
=> $false ) ).
fof(ax_disability_block,axiom,
! [F,X,Y,A,T] :
( ( proh(F)
& aee(F,X)
& aer(F,Y)
& act(F,A)
& tgt(F,T) )
=> ~ ? [Db] :
( disability(Db)
& bearer(Db,Y)
& cnt(Db,A,T) ) ) ).
fof(ax_odrl_rel_is_rel,axiom,
! [Rho] :
( odrl_rel(Rho)
=> legal_relator(Rho) ) ).
fof(ax_A1,axiom,
! [X,A,T,Q] :
( norm_state_change(X,A,T,Q)
=> ? [E] :
( inst_event(E)
& triggers(E,X,A,T,Q) ) ) ).
fof(ax_A2,axiom,
! [E] :
( inst_event(E)
=> ? [Y] : competent_for(Y,E) ) ).
fof(ax_A3,axiom,
! [Y,E] :
( competent_for(Y,E)
=> ? [Pw,S,X] :
( power(Pw)
& bearer(Pw,Y)
& about_event(Pw,E)
& subjection(S)
& bearer(S,X)
& about_event(S,E) ) ) ).
fof(ax_B1,axiom,
! [F,X,A,T] :
( ( proh(F)
& has_rem(F)
& act(F,A)
& tgt(F,T)
& aee(F,X)
& does(X,A,T) )
=> ? [B] :
( rem_act(F,B)
& norm_state_change(X,B,T,duty_rem) ) ) ).
fof(ax_B2,axiom,
! [Pw,A,T,Rho,E,R] :
( ( power(Pw)
& cnt(Pw,decl(A),T)
& part_of(Pw,Rho)
& founds_rem(E,Rho,R) )
=> about_event(Pw,E) ) ).
fof(ax_B3,axiom,
! [S,A,T,Rho,E,R] :
( ( subjection(S)
& cnt(S,decl(A),T)
& part_of(S,Rho)
& founds_rem(E,Rho,R) )
=> about_event(S,E) ) ).
fof(agent_bibliothek,axiom,
agent(bibliothek) ).
fof(agent_ensemble,axiom,
agent(ensemble) ).
fof(action_read,axiom,
action(read) ).
fof(target_theater,axiom,
target(theater_ds) ).
fof(rule_p1,axiom,
rule(p1) ).
fof(event_e1,axiom,
event(e1) ).
fof(perm_p1,axiom,
perm(p1) ).
fof(aee_p1,axiom,
aee(p1,bibliothek) ).
fof(aer_p1,axiom,
aer(p1,ensemble) ).
fof(act_p1,axiom,
act(p1,read) ).
fof(tgt_p1,axiom,
tgt(p1,theater_ds) ).
fof(act_e1_p1,axiom,
activates(e1,p1) ).
%--------------------------------------------------------------------------