%--------------------------------------------------------------------------
% File     : KRS292_1 : TPTP v9.3.1. Released v9.3.0.
% Domain   : Knowledge Representation
% Problem  : Unary and binary relations that hold with some confidence
% Version  : Especial
% English  : The problem is about unary and binary relations that hold with
%            some confidence level, where the confidence is expressed by a
%            non-negative number, 0 means "certain", and larger numbers 
%            mean lower confidence. Then brel(R,X,Y,N) means "X and Y are 
%            in the binary relation R with confidence N or better", and 
%            analogously urel(R,X,N) means "X is in the unary relation R 
%            with confidence N or better".

% Refs     : [Wal08] Waldmann (2008), Email to Geoff Sutcliffe
% Source   : [Wal08]
% Names    : brel.dfg [Wal08]

% Status   : Theorem
% Rating   : 0.40 v9.3.0
% Syntax   : Number of formulae    :   53 (  20 unt;  25 typ;   0 def)
%            Number of atoms       :   43 (   1 equ)
%            Maximal formula atoms :    3 (   1 avg)
%            Number of connectives :   15 (   0   ~;   0   |;   7   &)
%                                         (   0 <=>;   8  =>;   0  <=;   0 <~>)
%            Maximal formula depth :   10 (   3 avg)
%            Maximal term depth    :    3 (   1 avg)
%            Number arithmetic     :   41 (   2 atm;   5 fun;  19 num;  15 var)
%            Number of types       :    5 (   3 usr;   1 ari;   0 dat;   0 cdt)
%            Number of type conns  :   14 (   6   >;   8   *;   0   +;   0  <<)
%            Number of predicates  :    4 (   2 usr;   0 prp; 2-4 aty)
%            Number of functors    :   25 (  20 usr;  20 con; 0-2 aty)
%            Number of variables   :   44 (  43   !;   1   ?;  44   :)
% SPC      : TF0_THM_EQU_ARI_NDT

% Comments : 
%--------------------------------------------------------------------------
tff(unary_relation_type,type,
    unary_relation: $tType ).

tff(binary_relation_type,type,
    binary_relation: $tType ).

tff(thing_type,type,
    thing: $tType ).

tff(is_person,type,
    is_person: unary_relation ).

tff(is_city,type,
    is_city: unary_relation ).

tff(is_country,type,
    is_country: unary_relation ).

tff(is_continent,type,
    is_continent: unary_relation ).

tff(thomas_decl,type,
    thomas: thing ).

tff(john_decl,type,
    john: thing ).

tff(mary_decl,type,
    mary: thing ).

tff(newyork_decl,type,
    newyork: thing ).

tff(chicago_decl,type,
    chicago: thing ).

tff(berlin_decl,type,
    berlin: thing ).

tff(usa_decl,type,
    usa: thing ).

tff(germany_decl,type,
    germany: thing ).

tff(northamerica_decl,type,
    northamerica: thing ).

tff(europe_decl,type,
    europe: thing ).

tff(partof_decl,type,
    partof: binary_relation ).

tff(livesin_decl,type,
    livesin: binary_relation ).

tff(unary_relation_with_confidence_decl,type,
    unary_relation_with_confidence: ( unary_relation * thing * $int ) > $o ).

tff(inverse_decl,type,
    inverse: binary_relation > binary_relation ).

tff(binary_relation_with_confidence_decl,type,
    binary_relation_with_confidence: ( binary_relation * thing * thing * $int ) > $o ).

tff(compose_binary_binary_decl,type,
    compose_binary_binary: ( binary_relation * binary_relation ) > binary_relation ).

tff(compose_binary_unary_decl,type,
    compose_binary_unary: ( binary_relation * unary_relation ) > unary_relation ).

tff(compose_unary_binary_decl,type,
    compose_unary_binary: ( unary_relation * binary_relation ) > unary_relation ).

tff(ax1,axiom,
    ! [U: binary_relation,V: binary_relation,W: thing,X: thing,Y: thing,Z: $int,X1: $int] :
      ( ( binary_relation_with_confidence(U,W,X,Z)
        & binary_relation_with_confidence(V,X,Y,X1) )
     => binary_relation_with_confidence(compose_binary_binary(U,V),W,Y,$sum(Z,X1)) ) ).

tff(ax2,axiom,
    ! [U: binary_relation,V: unary_relation,W: thing,X: thing,Y: $int,Z: $int] :
      ( ( binary_relation_with_confidence(U,W,X,Y)
        & unary_relation_with_confidence(V,X,Z) )
     => unary_relation_with_confidence(compose_binary_unary(U,V),W,$sum(Y,Z)) ) ).

tff(ax3,axiom,
    ! [U: unary_relation,V: binary_relation,W: thing,X: thing,Z: $int,X1: $int] :
      ( ( unary_relation_with_confidence(U,W,Z)
        & binary_relation_with_confidence(V,W,X,X1) )
     => unary_relation_with_confidence(compose_unary_binary(U,V),X,$sum(Z,X1)) ) ).

tff(ax4,axiom,
    ! [U: binary_relation,V: thing,W: thing,X: $int] :
      ( binary_relation_with_confidence(U,V,W,X)
     => binary_relation_with_confidence(inverse(U),W,V,X) ) ).

tff(ax5,axiom,
    ! [U: binary_relation] : ( inverse(inverse(U)) = U ) ).

tff(ax6,axiom,
    ! [U: binary_relation,V: thing,W: thing,X: $int,Y: $int] :
      ( ( binary_relation_with_confidence(U,V,W,X)
        & $greatereq(Y,X) )
     => binary_relation_with_confidence(U,V,W,Y) ) ).

tff(ax7,axiom,
    ! [U: unary_relation,V: thing,W: $int,X: $int] :
      ( ( unary_relation_with_confidence(U,V,W)
        & $greatereq(X,W) )
     => unary_relation_with_confidence(U,V,X) ) ).

tff(ax8,axiom,
    ! [U: thing,V: thing,W: thing,X: $int,Y: $int] :
      ( ( binary_relation_with_confidence(livesin,U,V,X)
        & binary_relation_with_confidence(partof,V,W,Y) )
     => binary_relation_with_confidence(livesin,U,W,$sum(X,Y)) ) ).

tff(ax9,axiom,
    ! [U: thing,V: thing,W: thing,X: $int,Y: $int] :
      ( ( binary_relation_with_confidence(partof,U,V,X)
        & binary_relation_with_confidence(partof,V,W,Y) )
     => binary_relation_with_confidence(partof,U,W,$sum(X,Y)) ) ).

tff(ax10,axiom,
    binary_relation_with_confidence(livesin,john,newyork,1) ).

tff(ax11,axiom,
    binary_relation_with_confidence(livesin,mary,chicago,2) ).

tff(ax12,axiom,
    binary_relation_with_confidence(livesin,thomas,berlin,0) ).

tff(ax13,axiom,
    binary_relation_with_confidence(partof,berlin,germany,0) ).

tff(ax14,axiom,
    binary_relation_with_confidence(partof,germany,europe,0) ).

tff(ax15,axiom,
    binary_relation_with_confidence(partof,usa,northamerica,0) ).

tff(ax16,axiom,
    binary_relation_with_confidence(partof,newyork,usa,0) ).

tff(ax17,axiom,
    binary_relation_with_confidence(partof,chicago,usa,0) ).

tff(ax18,axiom,
    unary_relation_with_confidence(is_person,john,0) ).

tff(ax19,axiom,
    unary_relation_with_confidence(is_person,mary,0) ).

tff(ax20,axiom,
    unary_relation_with_confidence(is_person,thomas,0) ).

tff(ax21,axiom,
    unary_relation_with_confidence(is_city,newyork,0) ).

tff(ax22,axiom,
    unary_relation_with_confidence(is_city,chicago,0) ).

tff(ax23,axiom,
    unary_relation_with_confidence(is_city,berlin,0) ).

tff(ax24,axiom,
    unary_relation_with_confidence(is_country,usa,0) ).

tff(ax25,axiom,
    unary_relation_with_confidence(is_country,germany,0) ).

tff(ax26,axiom,
    unary_relation_with_confidence(is_continent,northamerica,0) ).

tff(ax27,axiom,
    unary_relation_with_confidence(is_continent,europe,0) ).

tff(co1,conjecture,
    ? [U: binary_relation] : binary_relation_with_confidence(U,john,mary,4) ).

%--------------------------------------------------------------------------