%------------------------------------------------------------------------------
% File     : GRA123^1 : TPTP v9.3.1. Released v9.3.0.
% Domain   : Graph Theory
% Problem  : Ramsey number r(3,5) = 14 with Peano axioms
% Version  : Especial.
% English  : The Ramsey property that if an undirected graph has at least
%            R(m,n) vertices, then it must have either an m-clique or an
%            n-anticlique.

% Refs     : [Ram30] Ramsey (1930), On a Problem of Formal Logic
%          : [Kal24] Kalizyk (2024), Email to G. Sutcliffe
% Source   : [Kal24]
% Names    : r_3_5_14_p [Kal24]

% Status   : Unsatisfiable
% Rating   : 1.00 v9.3.0
% Syntax   : Number of formulae    :    8 (   1 unt;   3 typ;   0 def)
%            Number of atoms       :   31 (  16 equ;   0 cnn)
%            Maximal formula atoms :   20 (   6 avg)
%            Number of connectives :   64 (   5   ~;  25   |;   0   &;  33   @)
%                                         (   0 <=>;   1  =>;   0  <=;   0 <~>)
%            Maximal formula depth :   27 (  11 avg)
%            Number of types       :    2 (   0 usr)
%            Number of type conns  :    3 (   3   >;   0   *;   0   +;   0  <<)
%            Number of symbols     :    4 (   3 usr;   1 con; 0-2 aty)
%            Number of variables   :   13 (   0   ^;  13   !;   0   ?;  13   :)
% SPC      : TH0_UNS_EQU_NAR_NDT

% Comments :
%------------------------------------------------------------------------------
thf(rtp,type,
    r: $i > $i > $o ).

thf(rsym,axiom,
    ! [X: $i,Y: $i] :
      ( ~ ( r @ X @ Y )
      | ( r @ Y @ X ) ) ).

thf(rno3cl,axiom,
    ! [X: $i,Y: $i,Z: $i] :
      ( ( X = Y )
      | ( X = Z )
      | ( Y = Z )
      | ~ ( r @ X @ Y )
      | ~ ( r @ X @ Z )
      | ~ ( r @ Y @ Z ) ) ).

thf(rno5acl,axiom,
    ! [X: $i,Y: $i,Z: $i,W: $i,U: $i] :
      ( ( X = Y )
      | ( X = Z )
      | ( Y = Z )
      | ( X = W )
      | ( Y = W )
      | ( Z = W )
      | ( X = U )
      | ( Y = U )
      | ( Z = U )
      | ( W = U )
      | ( r @ X @ Y )
      | ( r @ X @ Z )
      | ( r @ Y @ Z )
      | ( r @ X @ W )
      | ( r @ Y @ W )
      | ( r @ Z @ W )
      | ( r @ X @ U )
      | ( r @ Y @ U )
      | ( r @ Z @ U )
      | ( r @ W @ U ) ) ).

thf(ctp,type,
    c: $i ).

thf(ftp,type,
    f: $i > $i ).

thf(pfnc,axiom,
    ! [X: $i] :
      ( ( f @ X )
     != c ) ).

thf(pfinj,axiom,
    ! [X: $i,Y: $i] :
      ( ( ( f @ X )
        = ( f @ Y ) )
     => ( X = Y ) ) ).

%------------------------------------------------------------------------------