%------------------------------------------------------------------------------
% File     : GRA118^1 : TPTP v9.3.1. Released v9.3.0.
% Domain   : Graph Theory
% Problem  : Ramsey number r(3,3) = 6 with Peano axioms
% Version  : Especial.
% English  : The Ramsey property that if an undirected graph has at least
%            R(m,n) vertices, then it must have either an m-clique or an
%            n-anticlique.

% Refs     : [Ram30] Ramsey (1930), On a Problem of Formal Logic
%          : [Kal24] Kalizyk (2024), Email to G. Sutcliffe
% Source   : [Kal24]
% Names    : r_3_3_6_p [Kal24]

% Status   : Unsatisfiable
% Rating   : 0.00 v9.3.0
% Syntax   : Number of formulae    :    8 (   1 unt;   3 typ;   0 def)
%            Number of atoms       :   17 (   9 equ;   0 cnn)
%            Maximal formula atoms :    6 (   3 avg)
%            Number of connectives :   36 (   5   ~;  11   |;   0   &;  19   @)
%                                         (   0 <=>;   1  =>;   0  <=;   0 <~>)
%            Maximal formula depth :   12 (   7 avg)
%            Number of types       :    2 (   0 usr)
%            Number of type conns  :    3 (   3   >;   0   *;   0   +;   0  <<)
%            Number of symbols     :    4 (   3 usr;   1 con; 0-2 aty)
%            Number of variables   :   11 (   0   ^;  11   !;   0   ?;  11   :)
% SPC      : TH0_UNS_EQU_NAR_NDT

% Comments :
%------------------------------------------------------------------------------
thf(rtp,type,
    r: $i > $i > $o ).

thf(rsym,axiom,
    ! [X: $i,Y: $i] :
      ( ~ ( r @ X @ Y )
      | ( r @ Y @ X ) ) ).

thf(rno3cl,axiom,
    ! [X: $i,Y: $i,Z: $i] :
      ( ( X = Y )
      | ( X = Z )
      | ( Y = Z )
      | ~ ( r @ X @ Y )
      | ~ ( r @ X @ Z )
      | ~ ( r @ Y @ Z ) ) ).

thf(rno3acl,axiom,
    ! [X: $i,Y: $i,Z: $i] :
      ( ( X = Y )
      | ( X = Z )
      | ( Y = Z )
      | ( r @ X @ Y )
      | ( r @ X @ Z )
      | ( r @ Y @ Z ) ) ).

thf(ctp,type,
    c: $i ).

thf(ftp,type,
    f: $i > $i ).

thf(pfnc,axiom,
    ! [X: $i] :
      ( ( f @ X )
     != c ) ).

thf(pfinj,axiom,
    ! [X: $i,Y: $i] :
      ( ( ( f @ X )
        = ( f @ Y ) )
     => ( X = Y ) ) ).

%------------------------------------------------------------------------------