%--------------------------------------------------------------------------
% File     : MGT002+8 : TPTP v9.3.1. Released v9.3.0.
% Domain   : Management
% Axioms   : Well-formedness conditions for axis-specific constraints
% Version  : [Han98] axioms.
% English  : Encodes the three well-formedness conditions from the axis
%            profile definition: (i) V in D_k, (ii) op=lt implies 
%            V != inf, (iii) op=gt implies V != sup. Together they 
%            guarantee that every well-formed constraint has a non-empty
%            denotation (lem:totality). Also defines sem_nonempty/4 and
%            operator enumeration axioms.

% Refs     : [MC+26] Mustafa et al. (2026), Axis Decomposition for ODRL
% Source   : [MC+26]
% Names    : WF000-0.ax [MC+26]

% Status   : Satisfiable
% Syntax   : Number of formulae    :   26 (  15 unt;   0 def)
%            Number of atoms       :   48 (  17 equ)
%            Maximal formula atoms :    6 (   1 avg)
%            Number of connectives :   34 (  12   ~;   4   |;   7   &)
%                                         (   5 <=>;   6  =>;   0  <=;   0 <~>)
%            Maximal formula depth :    8 (   4 avg)
%            Maximal term depth    :    1 (   1 avg)
%            Number of predicates  :    5 (   4 usr;   0 prp; 1-4 aty)
%            Number of functors    :    5 (   5 usr;   5 con; 0-0 aty)
%            Number of variables   :   31 (  31   !;   0   ?)
% SPC      : FOF_SAT_RFO_SEQ

% Comments : Requires AXIS001+1.ax and ORD000-0.ax. Continuous domains
%            also requires ORD001-0.ax.
%--------------------------------------------------------------------------
%----Well-formedness predicate
%----wf(Op, V, InfD, SupD): constraint (ell_ak, Op, V) is well-formed over D_k.
%----  (i)   V in D_k             -- value is in the domain
%----  (ii)  Op=lt  => V != InfD  -- strict lower bound not at infimum
%----  (iii) Op=gt  => V != SupD  -- strict upper bound not at supremum
fof(wf_eq,axiom,
    ! [V,InfD,SupD] :
      ( wf(eq,V,InfD,SupD)
    <=> ( leq(InfD,V)
        & leq(V,SupD) ) ) ).

fof(wf_lteq,axiom,
    ! [V,InfD,SupD] :
      ( wf(lteq,V,InfD,SupD)
    <=> ( leq(InfD,V)
        & leq(V,SupD) ) ) ).

fof(wf_gteq,axiom,
    ! [V,InfD,SupD] :
      ( wf(gteq,V,InfD,SupD)
    <=> ( leq(InfD,V)
        & leq(V,SupD) ) ) ).

fof(wf_lt,axiom,
    ! [V,InfD,SupD] :
      ( wf(lt,V,InfD,SupD)
    <=> ( leq(InfD,V)
        & leq(V,SupD)
        & V != InfD ) ) ).

fof(wf_gt,axiom,
    ! [V,InfD,SupD] :
      ( wf(gt,V,InfD,SupD)
    <=> ( leq(InfD,V)
        & leq(V,SupD)
        & V != SupD ) ) ).

%----Non-emptiness guarantee
fof(nonempty_eq,axiom,
    ! [V,InfD,SupD] :
      ( wf(eq,V,InfD,SupD)
     => sem_nonempty(eq,V,InfD,SupD) ) ).

fof(nonempty_lteq,axiom,
    ! [V,InfD,SupD] :
      ( wf(lteq,V,InfD,SupD)
     => sem_nonempty(lteq,V,InfD,SupD) ) ).

fof(nonempty_gteq,axiom,
    ! [V,InfD,SupD] :
      ( wf(gteq,V,InfD,SupD)
     => sem_nonempty(gteq,V,InfD,SupD) ) ).

fof(nonempty_lt,axiom,
    ! [V,InfD,SupD] :
      ( wf(lt,V,InfD,SupD)
     => sem_nonempty(lt,V,InfD,SupD) ) ).

fof(nonempty_gt,axiom,
    ! [V,InfD,SupD] :
      ( wf(gt,V,InfD,SupD)
     => sem_nonempty(gt,V,InfD,SupD) ) ).

%----Operator enumeration
fof(op_eq_is_op,axiom,
    is_op(eq) ).

fof(op_lt_is_op,axiom,
    is_op(lt) ).

fof(op_lteq_is_op,axiom,
    is_op(lteq) ).

fof(op_gt_is_op,axiom,
    is_op(gt) ).

fof(op_gteq_is_op,axiom,
    is_op(gteq) ).

fof(ops_distinct_1,axiom,
    eq != lt ).

fof(ops_distinct_2,axiom,
    eq != lteq ).

fof(ops_distinct_3,axiom,
    eq != gt ).

fof(ops_distinct_4,axiom,
    eq != gteq ).

fof(ops_distinct_5,axiom,
    lt != lteq ).

fof(ops_distinct_6,axiom,
    lt != gt ).

fof(ops_distinct_7,axiom,
    lt != gteq ).

fof(ops_distinct_8,axiom,
    lteq != gt ).

fof(ops_distinct_9,axiom,
    lteq != gteq ).

fof(ops_distinct_10,axiom,
    gt != gteq ).

fof(op_enum,axiom,
    ! [Op] :
      ( is_op(Op)
     => ( Op = eq
        | Op = lt
        | Op = lteq
        | Op = gt
        | Op = gteq ) ) ).

%--------------------------------------------------------------------------