%------------------------------------------------------------------------------
% File     : DAT001_1 : TPTP v10.0.0. Released v10.0.0.
% Domain   : Data Structures
% Problem  :
% Version  : Especial.
% English  :

% Refs     :
% Source   : [TPTP]
% Names    :

% Status   : Theorem
% Rating   : ? v10.0.0
% Syntax   : Number of formulae    :   18 (   8 unt;  10 typ;   0 def)
%            Number of atoms       :    8 (   8 equ)
%            Maximal formula atoms :    1 (   1 avg)
%            Number of connectives :    0 (   0   ~;   0   |;   0   &)
%                                         (   0 <=>;   0  =>;   0  <=;   0 <~>)
%            Maximal formula depth :    4 (   3 avg)
%            Maximal term depth    :    3 (   2 avg)
%            Number of types       :    2 (   2 usr;   0 ari;   2 dat;   0 cdt)
%            Number of type conns  :    9 (   6   >;   3   *;   0   +;   0  <<)
%            Number of predicates  :    1 (   0 usr;   0 prp; 2-2 aty)
%            Number of functors    :    8 (   8 usr;   2 con; 0-2 aty)
%            Number of variables   :   12 (  12   !;   0   ?;  12   :)
% SPC      : TF0_THM_EQU_NAR_DAT

% Comments :
%------------------------------------------------------------------------------
tff(nat_type,type-datatype,
    nat: $tType ).

tff(lst_type,type-datatype,
    lst: $tType ).

tff(zero_type,type-datatype_constructor,
    zero: nat ).

tff(s_type,type-datatype_constructor,
    s: nat > nat ).

tff(nil_type,type-datatype_constructor,
    nil: lst ).

tff(cons_type,type-datatype_constructor,
    cons: ( nat * lst ) > lst ).

tff(app_type,type,
    app: ( lst * lst ) > lst ).

tff(rev_type,type,
    rev: lst > lst ).

tff(revAcc_type,type,
    revAcc: lst > lst ).

tff(revAccInner_type,type,
    revAccInner: ( lst * lst ) > lst ).

tff(1,axiom,
    ! [R: lst] : ( app(nil,R) = R ) ).

tff(2,axiom,
    ! [A: nat,L: lst,R: lst] : ( app(cons(A,L),R) = cons(A,app(L,R)) ) ).

tff(3,axiom,
    rev(nil) = nil ).

tff(4,axiom,
    ! [X: nat,Xs: lst] : ( rev(cons(X,Xs)) = app(rev(Xs),cons(X,nil)) ) ).

tff(5,axiom,
    ! [X: lst] : ( revAcc(X) = revAccInner(X,nil) ) ).

tff(6,axiom,
    ! [Acc: lst] : ( revAccInner(nil,Acc) = Acc ) ).

tff(7,axiom,
    ! [Acc: lst,X: nat,Xs: lst] : ( revAccInner(cons(X,Xs),Acc) = revAccInner(Xs,cons(X,Acc)) ) ).

tff(goal,conjecture,
    ! [X: lst] : ( revAcc(X) = rev(X) ) ).

%------------------------------------------------------------------------------