#!/bin/tcsh

setenv HERE `dirname $0`
set TimeLimit = $1
set Problem = $2
set Mode = $3

limit stack unlimited

set SPCLine=`grep "^% SPC " $Problem`
if ("$SPCLine" != "") then
    set ProblemSPC = `expr "$SPCLine" : "^% SPC  *: *\([^ ]*\)"`
else
    set ProblemSPC = `$HERE/SPCForProblem $Problem`
endif

cd $HERE
if ("$Mode" == "THM") then
    if (`expr "$ProblemSPC" : "TF0_.*ARI"`) then
        echo "Running TFA theorem proving"
        set Schedule = "tfa"
    else
        if (`expr "$ProblemSPC" : "CNF_.*UEQ"`) then
            echo "Running UEQ theorem proving"
            set Schedule = "ueq"
        else
            if (`expr "$ProblemSPC" : "CNF_.*EPR"`) then
                echo "Running EPR theorem proving"
                set Schedule = "epr"
            else
                echo "Running first-order theorem proving"
                set Schedule = "fof"
            endif
        endif
    endif
else
    echo "Running model finding"
    set Schedule = "fnt"
endif

set Command = "$HERE/iproveropt-multi-core-casc.sh -l tptp -s ${Schedule}_schedule -t $TimeLimit $Problem"
echo "Running: $Command"
$Command
