TPTP Problem File: SWB028+2.p
View Solutions
- Solve Problem
%------------------------------------------------------------------------------
% File : SWB028+2 : TPTP v8.2.0. Released v5.2.0.
% Domain : Semantic Web
% Problem : Inferred Property Characteristics III
% Version : [Sch11] axioms : Reduced > Incomplete.
% English :
% Refs : [Sch11] Schneider, M. (2011), Email to G. Sutcliffe
% Source : [Sch11]
% Names : 028_Inferred_Property_Characteristics_III [Sch11]
% Status : Theorem
% Rating : 0.22 v8.2.0, 0.19 v8.1.0, 0.22 v7.4.0, 0.17 v7.3.0, 0.10 v7.2.0, 0.07 v7.1.0, 0.00 v7.0.0, 0.07 v6.4.0, 0.08 v6.2.0, 0.16 v6.1.0, 0.20 v6.0.0, 0.17 v5.5.0, 0.22 v5.4.0, 0.25 v5.3.0, 0.26 v5.2.0
% Syntax : Number of formulae : 11 ( 2 unt; 0 def)
% Number of atoms : 42 ( 2 equ)
% Maximal formula atoms : 5 ( 3 avg)
% Number of connectives : 31 ( 0 ~; 0 |; 17 &)
% ( 8 <=>; 6 =>; 0 <=; 0 <~>)
% Maximal formula depth : 9 ( 6 avg)
% Maximal term depth : 1 ( 1 avg)
% Number of predicates : 5 ( 4 usr; 0 prp; 1-3 aty)
% Number of functors : 10 ( 10 usr; 10 con; 0-0 aty)
% Number of variables : 28 ( 26 !; 2 ?)
% SPC : FOF_THM_RFO_SEQ
% Comments :
%------------------------------------------------------------------------------
fof(owl_class_inversefunctionalproperty_type,axiom,
ic(uri_owl_InverseFunctionalProperty) ).
fof(owl_prop_inverseof_ext,axiom,
! [X,Y] :
( iext(uri_owl_inverseOf,X,Y)
=> ( ip(X)
& ip(Y) ) ) ).
fof(owl_prop_equivalentclass_ext,axiom,
! [X,Y] :
( iext(uri_owl_equivalentClass,X,Y)
=> ( ic(X)
& ic(Y) ) ) ).
fof(owl_char_functional,axiom,
! [P] :
( icext(uri_owl_FunctionalProperty,P)
<=> ( ip(P)
& ! [X,Y1,Y2] :
( ( iext(P,X,Y1)
& iext(P,X,Y2) )
=> Y1 = Y2 ) ) ) ).
fof(owl_char_inversefunctional,axiom,
! [P] :
( icext(uri_owl_InverseFunctionalProperty,P)
<=> ( ip(P)
& ! [X1,X2,Y] :
( ( iext(P,X1,Y)
& iext(P,X2,Y) )
=> X1 = X2 ) ) ) ).
fof(owl_rdfsext_subclassof,axiom,
! [C1,C2] :
( iext(uri_rdfs_subClassOf,C1,C2)
<=> ( ic(C1)
& ic(C2)
& ! [X] :
( icext(C1,X)
=> icext(C2,X) ) ) ) ).
fof(owl_eqdis_equivalentclass,axiom,
! [C1,C2] :
( iext(uri_owl_equivalentClass,C1,C2)
<=> ( ic(C1)
& ic(C2)
& ! [X] :
( icext(C1,X)
<=> icext(C2,X) ) ) ) ).
fof(owl_restrict_somevaluesfrom,axiom,
! [Z,P,C] :
( ( iext(uri_owl_someValuesFrom,Z,C)
& iext(uri_owl_onProperty,Z,P) )
=> ! [X] :
( icext(Z,X)
<=> ? [Y] :
( iext(P,X,Y)
& icext(C,Y) ) ) ) ).
fof(owl_inv,axiom,
! [P1,P2] :
( iext(uri_owl_inverseOf,P1,P2)
<=> ( ip(P1)
& ip(P2)
& ! [X,Y] :
( iext(P1,X,Y)
<=> iext(P2,Y,X) ) ) ) ).
fof(testcase_conclusion_fullish_028_Inferred_Property_Characteristics_III,conjecture,
iext(uri_rdfs_subClassOf,uri_ex_InversesOfFunctionalProperties,uri_owl_InverseFunctionalProperty) ).
fof(testcase_premise_fullish_028_Inferred_Property_Characteristics_III,axiom,
? [BNODE_z] :
( iext(uri_owl_equivalentClass,uri_ex_InversesOfFunctionalProperties,BNODE_z)
& iext(uri_rdf_type,BNODE_z,uri_owl_Restriction)
& iext(uri_owl_onProperty,BNODE_z,uri_owl_inverseOf)
& iext(uri_owl_someValuesFrom,BNODE_z,uri_owl_FunctionalProperty) ) ).
%------------------------------------------------------------------------------