TPTP Axioms File: PHI002+1.ax


%------------------------------------------------------------------------------
% File     : PHI002+1 : TPTP v7.5.0. Released v7.4.0.
% Domain   : Philosophy
% Axioms   : Axioms for Spinoza's Ethics - the DAPI
% Version  : [Hor19] axioms.
% English  :

% Refs     : [Hor19] Horner (2019), A Computationally Assisted Reconstructi
%            [Hor20] Horner (2020), Email to Geoff Sutcliffe
% Source   : [Hor20]
% Names    :

% Status   : Satisfiable
% Syntax   : Number of formulae    :    7 (   0 unit)
%            Number of atoms       :   24 (   2 equality)
%            Maximal formula depth :    8 (   6 average)
%            Number of connectives :   27 (  10   ~;   2   |;   7   &)
%                                         (   2 <=>;   6  =>;   0  <=;   0 <~>)
%                                         (   0  ~|;   0  ~&)
%            Number of predicates  :   17 (   0 propositional; 1-2 arity)
%            Number of functors    :    0 (   0 constant; --- arity)
%            Number of variables   :   13 (   0 sgn;  13   !;   0   ?)
%            Maximal term depth    :    1 (   1 average)
% SPC      : FOF_SAT_RFO_SEQ

% Comments : Requires PHI002+0.ax
%------------------------------------------------------------------------------
%----Axiom I. Everything which exists, exists either in itself or in something 
%----else.
fof(exists,axiom,(
    ! [X,Y] :
      ( exists(X)
    <=> ( existsIn(X,X)
        | ( existsIn(X,Y)
          & X != Y ) ) ) )).

%----Axiom II. That which cannot be conceived through itself must be conceived 
%----through something else.
fof(conceived_through,axiom,(
    ! [X,Y] :
      ( ~ conceivedThru(X,X)
     => ( conceivedThru(X,Y)
        & X != Y ) ) )).

%----Axiom III. From a given definite cause an effect necessarily follows; 
%----and, on the other hand, if no definite cause be granted, it is impossible 
%----that an effect can follow.
fof(definite_cause,axiom,(
    ! [X,Y] :
      ( definiteCause(X)
     => ( effectNecessarilyFollowsFrom(Y,X)
        & ( ~ definiteCause(X)
         => ~ effectNecessarilyFollowsFrom(Y,X) ) ) ) )).

%----Axiom IV. The knowledge of an effect depends on and involves the knowledge 
%----of a cause. 
fof(knowledge_of_effect,axiom,(
    ! [X,Y] :
      ( knowledgeOfEffect(X,Y)
    <=> knowledgeOfACause(X) ) )).

%----Axiom V. Things which have nothing in common cannot be understood, the 
%----one by the means of the other the one by means of the other; the 
%----conception of one does not involve the conception of the other. 
fof(have_nothing_in_common,axiom,(
    ! [X,Y] :
      ( haveNothingInCommon(X,Y)
     => ( ~ canBeUnderstoodInTermsOf(X,Y)
        & ~ canBeUnderstoodInTermsOf(Y,X)
        & ~ conceptionInvolves(X,Y)
        & ~ conceptionInvolves(Y,X) ) ) )).

%----Axiom VI. A true idea must correspond with its ideate or object. 
fof(true_idea,axiom,(
    ! [X,Y] :
      ( trueIdea(X)
     => ( correspondWith(X,Y)
        & ( ideateOf(Y,X)
          | objectOf(Y,X) ) ) ) )).

%----Axiom VII. If a thing can be conceived as non-existing, its essence does 
%----not involve its existence. 
fof(can_be_conceived_as_non_existing,axiom,(
    ! [X] :
      ( canBeConceivedAsNonExisting(X)
     => ~ essenceInvExistence(X) ) )).

%------------------------------------------------------------------------------