Testing

Abraham Lincoln is a Mammal

• Prove that Abraham Lincoln is a mammal

  fof(kb_SUMO_28,axiom,(
      ! [V__X,V__Y,V__Z] :
        ( ( is_instance(V__Y,'SetOrClass')
          & is_instance(V__X,'SetOrClass') )
       => ( ( subclass(V__X,V__Y)
            & is_instance(V__Z,V__X) )
         => is_instance(V__Z,V__Y) ) ) )).
  
  fof(kb_SUMO_5811,axiom,(
      is_instance('Mammal','SetOrClass') )).
  
  fof(kb_SUMO_5813,axiom,(
      subclass('Primate','Mammal') )).
  
  fof(kb_SUMO_5818,axiom,(
      is_instance('Primate','SetOrClass') )).
  
  fof(kb_SUMO_5823,axiom,(
      subclass('Hominid','Primate') )).
  
  fof(kb_SUMO_5824,axiom,(
      is_instance('Hominid','SetOrClass') )).
  
  fof(kb_SUMO_5826,axiom,(
      subclass('Human','Hominid') )).
  
  fof(kb_SUMO_5836,axiom,(
      is_instance('Human','SetOrClass') )).
  
  % fof(cheat,axiom,is_instance('Abraham Lincoln','Human')).
  
  fof(abe_mammal,conjecture,(
      is_instance('Abraham Lincoln','Mammal') )).

• YAGOSUMO facts and SUMO ontology (internal)
• 188 requests queued, 175 sent, 266 axioms delivered, 1 axiom used
• 15s CPU, 18s WC. 5863 clauses derived.

An Early 18th Century Composer

• Name a composer born in the first half of the 18th century

  fof(who,conjecture,
      ? [Composer,BirthDay,BirthMonth,BirthYear] :
        ( is_instance(Composer,'Composer')
        & is_birthdate(Composer,BirthDay,BirthMonth,BirthYear)
        & $greatereq(BirthYear,1700)
        & $lesseq(BirthYear,1750)
        & print(printall(nl,nl,'The composer is ',Composer,' born in ',BirthYear,nl)) ) ).

• YAGOSUMO facts, Arithmetic
• 515 requests queued, 427 sent, 456 axioms delivered, 2 axioms used
• 18s CPU, 26s WC. 7600 clauses derived.

Prize Winning Curies

• Name all Nobel prizes won by members of the Curie family

  fof(who,conjecture,
      ? [FullName,GivenName,Prize] :
        ( is_familyName('Curie',FullName)
        & has_WonPrize(FullName,Prize)
        & is_givenName(GivenName,FullName)
        & printonly(printall(nl,nl,GivenName,' won the ',Prize,nl)) ) ).

• YAGOSUMO facts
• 32 requests queued, 32 sent, 31 axioms delivered, 11 axioms used
• 2s CPU, 14s WC. 10 clauses derived.

An OECD Capital at the Same Latitude as Moscow that could get Flooded

• Name an OECD country's capital that is at the same latitude as Moscow (to the nearest degree), that could get flooded

  %----These come from SUMO
  fof(kb_SUMO_28,axiom,(
      ! [V__X,V__Y,V__Z] :
        ( ( s__instance(V__Y,s__SetOrClass)
          & s__instance(V__X,s__SetOrClass) )
       => ( ( s__subclass(V__X,V__Y)
            & s__instance(V__Z,V__X) )
         => s__instance(V__Z,V__Y) ) ) )).
  
  fof(kb_SUMO_MILO_6297,axiom,(
      s__instance(s__WaterArea,s__SetOrClass) )).
  
  fof(kb_SUMO_MILO_10029,axiom,(
      s__instance(s__BodyOfWater,s__SetOrClass) )).
  
  fof(kb_SUMO_MILO_DOMAINS_9645,axiom,(
      s__subclass(s__Sea,s__BodyOfWater) )).
  
  fof(kb_SUMO_MILO_DOMAINS_9546,axiom,(
      s__subclass(s__BodyOfWater,s__WaterArea) )).
  
  fof(kb_SUMO_MILO_DOMAINS_80407,axiom,(
      s__instance(s__Sea,s__SetOrClass) )).
  
  %----These are supplied by Geoff
  fof(flood_near_water,axiom,
      ! [W,C] :
        ( ( s__orientation(C,W,s__Near)
          & s__instance(W,s__WaterArea) )
       => s__capability(s__Flooding,s__located__m,C) ) ).
  
  fof(coastal_cities_near_water,axiom,
      ! [City] :
        ( is_instance(City,'Coastal Cities Class')
       => ? [Sea] :
            ( s__instance(Sea,s__Sea) 
            & s__orientation(City,Sea,s__Near) ) ) ).
  
  fof(where,conjecture,
      ? [City,Country,CityLat,CityLong,CityName,CityCountry,Latitude,
         MoscowLat,MoscowLong,MoscowName,MoscowCountry] :
        ( is_instance(Country,'OECD Member Economies Class')
        & capital_city(City,Country)
        & look_different(City,'Moscow')
        & latlong(City,CityLat,CityLong,CityName,CityCountry)
        & $evaleq($to_int(CityLat),Latitude)
        & latlong('Moscow',MoscowLat,MoscowLong,MoscowName,MoscowCountry)
        & $evaleq($to_int(MoscowLat),Latitude)
        & s__capability(s__Flooding,s__located__m,City)
        & print(printall(nl,nl,'The city is ',City,' in ',Country,
  ' at latitude ',CityLat,' (Moscow is at ',MoscowLat,')',nl,nl)) ) ).

• Needs preemptive requests for axioms (-IANo=0)
• YAGOSUMO facts, Yahoo map services, Arithmetic, Syntactic difference SUMO ontology (internal)
• 230 requests queued, 227 sent, 321 axioms delivered, 11 axioms used
• 3s CPU, 19s WC. 1047 clauses derived.